Основы Maple

Robert M. Corless
Department of Applied Mathematics
University of Western Ontario
London, Canada

Copyright 2001 by Robert M. Corless
All rights reserved

Useful one-word commands

Использование монокоманд

Plotting in Maple

Графика в Maple

Contour plots and other plots

Контурные графики и другие рисунки

> restart;

> with(plots):

Warning, the name changecoords has been redefined

>f1 := sin(y-x^2-1) + cos(2*y^2-x);

> contourplot( f1, x=-2..2, y=-2..2, grid=[100,100], colour=black, scaling=CONSTRAINED, axes=BOXED);

>f2 := y + sin(x^2*y-1/x);

> contourplot( f2, x=-Pi..Pi, y=-Pi..Pi, grid=[100,100], colour=black, axes=BOXED, scaling=CONSTRAINED );

> restart;

> tacnode := 2*x^4 - 3*x^2*y + y^4 - 2*y^3 + y^2;

> algcurves[plot_real_curve]( tacnode, x, y, colorOfCurve=COLOR(RGB,0,0,0), axes=NONE, view=[-2..2,-1..3] );

> plots[implicitplot]( tacnode, x=-2..2, y=-1..3, axes=NONE, colour=BLACK, view=[-2..2,-1..3] );

> plots[implicitplot]( tacnode, x=-2..2, y=-1..3, grid=[100,100], axes=NONE, colour=BLACK, view=[-2..2,-1..3] );

> plots[implicitplot]( tacnode, x=-2..2, y=-1..3, grid=[400,400], axes=NONE, colour=BLACK, view=[-2..2,-1..3] );

> algcurves[plot_real_curve]( y*exp(y)-x, x, y, force=true );

> restart;

> with(plots):

> van_der_Pol := diff(x(t),t,t) - epsilon*(1-x(t)^2)*diff(x(t),t) + x(t);

>eq1 := eval(van_der_Pol,epsilon=1):

>eq500 := eval(van_der_Pol,epsilon=500):

>sol1 := dsolve( {eq1,x(0)=2,D(x)(0)=0}, x(t), numeric,
range=0..10, stiff=true );

> plots[odeplot]( sol1, [x(t),diff(x(t),t)], colour=black );

>sol500 := dsolve( {eq500,x(0)=2,D(x)(0)=0}, x(t), numeric,
range=0..1000, stiff=true );

> plots[odeplot]( sol500, [x(t),diff(x(t),t)], colour=black );

> BenderOrszag := diff(y(t),t) = cos(Pi*t*y(t));

>sols := {seq(dsolve({BenderOrszag,y(0)=k/5},y(t),numeric,range=0..5),k=0..20)}:

>plts := {seq(odeplot(sols[i],[t,y(t)],colour=black),i=1..nops(sols))}:

> display( plts );

> PredatorPrey := {diff(x(t),t) = -3*x(t)+4*x(t)^2-x(t)*y(t)/2-x(t)^3,
diff(y(t),t) = -2.1*y(t)+x(t)*y(t)};

>ics := [seq({x(0)=4,y(0)=k/8},k=0..32)]:

>sols := {seq( dsolve( PredatorPrey union ics[i], {x(t),y(t)}, numeric, range=0..100 ),i=1..nops(ics)) }:

>plts := { seq(odeplot(sols[i],[x(t),y(t)],colour=black),i=1..nops(sols)) }:

> display( plts );

С официального разрешения © 2002 Waterloo Maple, Inc